BLOG

Go to top


いつもやってるブロックタグの記述

May 25, 2009 3:17 PM

いつも以下のような形で書くようにしていて、こうしておけばどんな場合でも必ず以下のようなことが出来ます。

  • 最初と最後だけ出力するための、ナントカ Header とかナントカ Footer が使える。
  • ナントカ Count ファンクションタグで総数を取得できる。
  • ループ変数(「__first__」,「__last__」,「__odd__」,「__even__」,「__counter__」)が使える。
  • 一件もない場合は <MTElse> の部分が出力される。

コピペして使うようにして、僕が作ったブロックタグは常にこういう仕様ですよ、とテンプレートをいじる人に伝えておけば、お互い何かと安心。

package MT::Plugin::SampleEntries;
use strict;

use MT;
use MT::Plugin;

use base qw( MT::Plugin );

our $VERSION = 0.1;

@MT::Plugin::SampleEntries::ISA = qw( MT::Plugin );

my $plugin = new MT::Plugin::SampleEntries( {
    name => 'SampleEntries',
    id => 'SampleEntries',
    key => 'sampleentries',
    version => $VERSION,
} );

MT->add_plugin( $plugin );

sub init_registry {
    my $plugin = shift;
    $plugin->registry( {
        tags => {
            block => {
                SampleEntries => \&_hdlr_sample_entries,
                SampleEntriesHeader => \&_hdlr_pass_tokens,
                SampleEntriesFooter => \&_hdlr_pass_tokens,
            },
            function => {
                SampleEntriesCount => \&_hdlr_sample_entries,
            },
        },
   } );
}

sub _hdlr_sample_entries {
    my ( $ctx, $args, $cond ) = @_;
    my $builder = $ctx->stash( 'builder' );
    my $tokens = $ctx->stash( 'tokens' );
    my $blog = $ctx->stash( 'blog' );
    
    my ( %terms, %args );
    $terms{ status } = $args->{ status } || MT::Entry::RELEASE();

    if ( $args->{ id } ) {
        $terms{ id } = $args->{ id };
    } else {
        $terms{ blog_id } = $args->{ blog_id } || $blog->id;
        $terms{ class } = $args->{ class } || 'entry';
        $args{ limit } = $args->{ limit } || $blog->entries_on_index;
        $args{ 'sort' } = $args->{ sort_by } || 'authored_on';
        $args{ direction } = $args->{ sort_order } || 'descend';
        $args{ offset } = $args->{ offset } || 0;
    }

    my @entries = MT::Entry->load( \%terms, \%args );
    if ( lc $ctx->stash( 'tag' ) eq 'sampleentriescount' ) {
        return scalar @entries;
    }

    my $res = ''; my $i = 0;
    my $vars = $ctx->{ __stash }{ vars } ||= {};
    if ( @entries ) {
        for my $entry ( @entries ) {
            local $vars->{ __first__ } = ! $i;
            local $vars->{ __last__ } = ! defined $entries[ $i + 1 ];
            local $vars->{ __odd__ } = ( $i % 2 ) == 0;
            local $vars->{ __even__ } = ( $i % 2 ) == 1;
            local $vars->{ __counter__ } = $i + 1;
            local $ctx->{ __stash }{ entry } = $entry;
            local $ctx->{ __stash }{ blog } = $entry->blog;
            local $ctx->{ __stash }{ blog_id } = $entry->blog_id;
            local $ctx->{ current_timestamp } = $entry->modified_on;
            local $ctx->{ modification_timestamp } = $entry->modified_on;
            my $out = $builder->build( $ctx, $tokens, { %$cond,
                                                        SampleEntriesHeader => ! $i,
                                                        SampleEntriesFooter => 
                                                            !defined $entries[ $i + 1 ],
                                     } );
            $res .= $out if $out;
            $i++;
        }
        return $res || '';
    } else {
        return $ctx->_hdlr_pass_tokens_else( @_ );
    }
}

sub _hdlr_pass_tokens {
    my( $ctx, $args, $cond ) = @_;
    my $b = $ctx->stash( 'builder' );
    defined( my $out = $b->build( $ctx, $ctx->stash( 'tokens' ), $cond ) )
        or return $ctx->error( $b->errstr );
    return $out;
}

1;

<MTElse> がブロックタグで使えると少なからず便利だし、テンプレートでいちいちナントカ Count の数を取得して分岐していると、ブロックタグでの処理と似たような load 方法を使うので、全体として処理に無駄が発生することになリがちです。軽くない Movable Type が重い Movable Type にならないようにするための地味な努力ですね。

Comments


Contact me

Copyright © 2005 - 2017 okayama All rights reserved.